erreur 0x800710d9 problème de cryptographie

Tutoriels, Astuces pour Windows

Modérateur : Mods Windows

Malekal_morte
Messages : 110638
Inscription : 10 sept. 2005 13:57

erreur 0x800710d9 problème de cryptographie

par Malekal_morte »

Si vous rencontrez l'erreur 0x800710d9.
Ce fix peut corriger aussi les problèmes de connexion au site sécurisé avec Internet Explorer.

- Selectionnez le texte ci-dessous
@echo off
:: Batch file that tries to remedy error # 800710D9
:: "Unable to read from or write to the database".
:: Author: Torgeir Bakken
:: Date: 2004-08-30

cls
echo This batch file will now try to remedy the error 0x800710D9.
echo To abort and not run it now, hold down Ctrl and press C.
echo Otherwise press the space bar to continue.
pause

:: Stop the Cryptographic service
%SystemRoot%\System32\net.exe stop CryptSvc

:: Rename all log files in the %SystemRoot%\Security folder
FOR %%a in (%SystemRoot%\Security\*.log) DO move /y %%a %%a.old

:: Rename the %SystemRoot%\System32\CatRoot2 folder
move /y %SystemRoot%\System32\CatRoot2 %SystemRoot%\System32\CatRoot2old

IF not exist %SystemRoot%\System32\CatRoot2 GOTO CONT01

:: In case the folder rename failed because of locked files
:: rename all log files in the %SystemRoot%\System32\CatRoot2 folder
FOR %%a in (%SystemRoot%\System32\CatRoot2\*.log) DO move /y %%a %%a.old
SET catroot2locked=True

:CONT01
cls
echo.
echo Please wait, this might take some time...

:: Unregister DLL files that are associated with Cryptographic Services
CD /D %SystemRoot%\System32
start /wait regsvr32.exe /s /u softpub.dll
start /wait regsvr32.exe /s /u wintrust.dll
start /wait regsvr32.exe /s /u initpki.dll
start /wait regsvr32.exe /s /u dssenh.dll
start /wait regsvr32.exe /s /u rsaenh.dll
start /wait regsvr32.exe /s /u gpkcsp.dll
start /wait regsvr32.exe /s /u sccbase.dll
start /wait regsvr32.exe /s /u slbcsp.dll
start /wait regsvr32.exe /s /u cryptdlg.dll

:: Reregister DLL files that are associated with Cryptographic Services
start /wait regsvr32.exe /s softpub.dll
start /wait regsvr32.exe /s wintrust.dll
start /wait regsvr32.exe /s initpki.dll
start /wait regsvr32.exe /s dssenh.dll
start /wait regsvr32.exe /s rsaenh.dll
start /wait regsvr32.exe /s gpkcsp.dll
start /wait regsvr32.exe /s sccbase.dll
start /wait regsvr32.exe /s slbcsp.dll
start /wait regsvr32.exe /s cryptdlg.dll

:: Configure and start the Cryptographic service
%SystemRoot%\system32\sc.exe config CryptSvc start= auto
:: Start the Cryptographic Service
%SystemRoot%\system32\net.exe start CryptSvc
cls

echo.
If "%catroot2locked%"=="True" GOTO CONT02
echo Finished, please reboot the computer and then try to install SP2 again...

GOTO END
:CONT02
echo Please run the batch file again with a newly restarted computer...
echo (but if it is newly restarted, just do a reboot and then try
echo to install SP2 again)...
GOTO END

:END
echo.
pause
- Ouvrez le Bloc-Note
- Edition/coller
- Enregistrez le fichier sous le nom fix.cmd
- Double-clicquez sur fix.cmd

Fix provenant de : http://www.andrew.cmu.edu/org/hc-tools/ ... /fixdb.bat
Première règle élémentaire de sécurité : on réfléchit puis on clic et pas l'inverse - Les fichiers/programmes c'est comme les bonbons, quand ça vient d'un inconnu, on n'accepte pas !
Comment protéger son PC des virus
Windows 11 : Compatibilité, Configuration minimale requise, télécharger ISO et installer Windows 11

Comment demander de l'aide sur le forum
Partagez malekal.com : n'hésitez pas à partager les articles qui vous plaisent sur la page Facebook du site.
  • Sujets similaires
    Réponses
    Vues
    Dernier message

Revenir à « Tutoriels Windows »